AutoCAD內常用術語的自動標注方法

2016-11-01 by:CAE仿真在線來源:互聯(lián)網(wǎng)

漢字的標注在CAD設計制圖中是一個重要的部分,也是一個較為繁瑣、困難的部分。目前,在AutoCAD內漢字的輸入大多采用拼音方式,對拼音不熟悉的人來說漢字的輸入就很困難。如果能將設計中常用的文字術語直觀地顯示出來供設計人員調用,將會極大地提高工作效率。本文就此進行研究,提出了一種用對話框(下圖)將常用術語顯示并供調用的方法,同時給出了源程序,供大家參考。該程序已應用于我院的實際生產(chǎn)中。

二、原理及方法

AutoCAD對話框結構包含有多種構件,如edit_box(編輯框)、list_box(列表框)、radio_button(多選一按鈕)等,利用這些工具,可以開發(fā)出界面友好的實用程序。
左圖就是用這種方法實現(xiàn)的。將常用詞組分類,分別存于不同的文件中。根據(jù)多選一按鈕中所驅動的分組號分別打開不同的文件,將文件內容讀入并顯示于列表框內,供設計人員使用。同時,設有一個編輯框,可將所點取的詞組顯示于編輯框中,便于用戶對詞組進行適當?shù)男薷?如刪除或增加字符等。這種方法有一個優(yōu)點,用戶可十分方便地根據(jù)自己需要修改或添加詞組內容。對話框文件及驅動程序分別見#CAL.DCL及#CAL.LSP。
三、程序使用方法
先用WPS、EDIT等編輯程序分類建立詞組庫(注意,需要存成純文本格式),每個詞組占一行。程序要求將"常用術語"、"圖紙名稱"、"房間名稱"等各分類所對應的詞組庫文件名分別為$TXT1.DAT、$TXT2.DAT、$TXT3.DAT厖。除第一個文件不能少外,其它文件可空缺,但當點取該分類項時,系統(tǒng)會提示有關文件不存在的信息。
然后將所建立的詞組庫文件及所提供的程序#TXT.LSP和對話框文件#TXT.DCL拷貝到AutoCAD所能找到的目錄(環(huán)境變量ACAD所設置的任一目錄如ACAD\SUPPORT或當前目錄)中,在Command:命令下鍵入(LOAD "#TXT")進行程序的加載,即可象其它AutoCAD內部命令一樣使用#TXT了。也可在所使用的菜單文件(如ACAD.MNU)中的下拉式菜單或屏幕菜單部分加上下面一行:[常用詞組]^C^C^P(if (null c:#txt) (load"#txt")) #txt以后可直接從菜單中驅動該程序。
在COMMAND:狀態(tài)下,鍵入#TXT后,系統(tǒng)彈出一個對話框,根據(jù)需要點取所需的詞組類別,再從列表框內選擇所需詞組。所點取的詞組會在編輯框[所選詞組]中顯示。用戶可以在此對詞組進行必要的修改,點取[OK]后,根據(jù)提示輸入字高及起點即可把詞組寫到圖中。
需要說明的是,本程序中是將文字以"HZ"字型寫到圖中,要求字體為TXT.SHX及HZTXT.SHX。若您的軟件中無這兩種字體,可將其它字體改名為該兩種字體(要求一個為英文字體,一個為中文字體),或將程序修改為您所具有的字體。但需要注意,也許您的字體在用于設置字型時會多一個選項,詢問是否垂直書寫文字,此時,可將字型設置一句改為:(command "STYLE" "HZ" "txt,hztxt" 0 0.7 0 "n" "n" "n")即可。

本程序在AutoCAD R12.0 FOR DOS及FOR WINDOWS版上均調試通過。
(defun c:#txt ( / oldcmd olderr ok txt_tb txt dcl_id sty fp nn ht pt txterr diag init wr_txt old_nn)
; 定義錯誤處理子程序
(defun txterr(s)
(if (and (/= s "console break")
(/= s "Function cancelled")
(/= s "quit / exit abort")
)
(princ (strcat "\nError:" s))
)
(if olderr (setq *error* olderr)); 恢復原系統(tǒng)設置
(if oldcmd (setvar "cmdecho" oldcmd))
(princ)
)
; 對話框顯示及驅動程序
(defun diag ( / i)
(if (> (setq dcl_id (load_dialog "#txt")) 0);加載對話框文件
(progn
(if (new_dialog "filetext" dcl [JX*6]id); 顯示對話框
(progn start_list "what");將詞組顯示到列表框內
(mapcar 'add_list txt_tb
)
(end_list)
(setq i 1)
(repeat nn;點取詞組分類項后的操作
(action_tile (strcat "c" (itoa i)) "(wr_txt)")
(setq i (1+ i))
)
(action_tile "what" "(setq i (atoi $value));選中詞組
(setq txt (nth i txt_tb))(set_tile \"sel_ok\" txt)"
)
(action_tile "sel_ok" "(setq txt $value)")
(action_tile "accept" "(setq ok T)(done_dialog 1)(unload_dialog dcl_id)")
(action_tile "cancel" "(unload_dialog dcl_id)")
(start_dialog)
)
(prompt "\n無法顯示對話框FILETEXT! 請檢查對話框內容!")
)
)
(prompt "\n無法加載對話框文件#TXT.DCL! 請檢查文件是否存在及路徑是否正確!")
)
)
; 初始化程序, 把第1個分組項中的詞組讀入表txt_tb中
(defun init( / fname fp txt1)
(setq fname (findfile "$txt1.dat"))
(if (not fname)
(progn (princ "\n文件 $TXT1.DAT 不存在 !") (exit)) ; 文件不存在, 則退出
)
(setq fp (open fname "r"))
(setq txt_tb '())
(while (setq txt1 (read_line fp))
(setq txt_tb (cons txt1 txt_tb))
)
(close fp)
(setq txt_tb (reverse txt_tb))
(setq old_nn 1);記錄索引號
)
; 更換列表框內詞組顯示內容
(defun wr_txt ( / fname fname1 fp txt1 i)
(setq i 1)
(while (<= i nn); 判別哪個詞組項被點中
(if (= (get_tile (strcat "c" (itoa i))) "1")
(setq fname1 (strcat "$txt" (itoa i) ".dat")
i nn
)
)
(setq i (1+ i))
)
(if (setq fname (findfile fname1)); 查找文件是否存在
(progn
(setq old_nn (atoi (substr fname1 5)));記錄索引號
(setq fp (open fname "r"))
(setq txt_tb '())
(while (setq txt1 (read_line fp));依次讀出各詞組
(setq txt_tb (cons txt1 txt_tb))
)
(close fp)
(setq txt_tb (reverse txt_tb))
(start_list "what");在列表框內顯示詞組內容
(mapcar 'add_list txt_tb)
(end_list)
) ; progn
(progn
(alert (strcat "文件" fname1 "不存在!"))
(set_tile (strcat "c" (itoa old_nn)) "1");恢復原記錄號
)
) ; if
)
; 主程序開始
(setq olderr *error*
*error* txterr
oldcmd (getvar "cmdecho")
)
(setvar "cmdecho" 0) ; 命令不回顯
(setq nn 9) ; 詞組分類數(shù)
(init) ; 初始化
(diag) ; 驅動對話框
(if (and ok txt)
(progn
(if (or (= (setq sty (tblsearch "STYLE" "HZ")) nil); "HZ"字型是否存在
(/= (cdr (assoc 40 sty)) 0) ; 字高是否為定值
(/=(getvar "TEXTSTYLE") "HZ"); 當前字型是否為"HZ"
)
(command "STYLE" "HZ" "txt,hztxt" 0 0.7 0 "n" "n") ; 設置"HZ"字型
)
(initget (+ 2 4));下面的輸入值要求大于0
(setq ht (getreal "\n請輸入字高<500>:"))
(if (not ht) (setq ht 500))
(setq pt (getpoint "\n請點取文字起點:"))
(command "text" pt ht 0 txt)
)
)
(setq *error* olderr);恢復原設置
(setvar "cmdecho" oldcmd)
(princ)
)
// #txt.dcl
// 供#txt.lsp調用
filetext : dialog { // 對話框名稱
label = "常用詞組"; // 對話框標識
: row {
: boxed_column {
label = " 索引 ";
: radio_button {
label = "常用術語"; // 多選一按鈕
key = "c1";
value = "1"; // 初始值為"1", 表示選中
}
: radio_button {
label = "圖紙名稱";
key = "c2";
}
: radio_button {
label = "房間名稱";
key = "c3";
}
: radio_button {
label = "衛(wèi)生器具";
key = "c4";
}
: radio_button {
label = "管材配件";
key = "c5";
}
: radio_button {
label = "器材儀表";
key = "c6";
}
: radio_button {
label = "常用設備";
key = "c7";
}
: radio_button {
label = "構筑物";
key = "c8";
}
: radio_button {
label = "其它";
key = "c9";
}
}
: list_box {
label = "詞組內容";
key = "what";
height = 15;
width = 26;
allow_accept = true; // 可雙擊鼠標選取
}
}
spacer_1;
: edit_box {// 編輯框
label = "所選詞組:";
key = "sel_ok";
}
spacer_1;// 增加間距
ok_cancel;
}